'Dumb RF Module example Transmitter code By GoodToGo! 31/05/17

'Transmitter code

option Explicit

dim STX$ as string = chr$(&h02) 'Start Byte
dim ETX$ as string = chr$(&h03) 'End Byte
dim Slice$ as string = "UUUUUUUUUUUUUUU" 'For RF module calibration
dim Message$ as string
dim Payload$ as string
dim i as integer

Message$ = "He sells seashells by the seashore"

Open "COM1:9600" as #1
Payload$ = Message$ + Chksum(Message$) 'Adds the checksum to the Message
do
print "Sending Payload"
for i = 1 to 4
Print #1, Slice$ + STX$ + Payload$ + ETX$
next i
pause 5000
loop

function Chksum(Message$) as string 'Creates Checksum of the Payload
local c as integer = 0
local b as integer = 0
local i as integer = len(Message$)
local a$ as string
do while (i) > 0
a$ = "&b"+bin$(asc(mid$(Message$,i,1)))
c = val(a$)
b = b xor c
i=i-1
loop
Chksum = chr$(b)
end function

'Dumb RF Module example Receiver code by GoodToGo! 31/05/17

'Receiver Code

option explicit

dim STX$ as string = chr$(&h02) 'Start Byte
dim ETX$ as string = chr$(&h03) 'End Byte
const MaxMsgLength =50 'Change if your Message is going to be higher
dim Rcvdata$ as string
dim RxdMsg$ as string
dim RxdDataFlag as integer = 0
dim InvalidMsgFlag as integer = 0
dim ValidMsgFlag as integer = 0

dim Debug = 0 'Change to 1 for extra info to the Console

open "com1:9600" as #1

'Main Loop
do
'Stuff goes here
If InvalidMsgFlag then InvalidMessage
If ValidMsgFlag then PrintMessage
if loc(#1) > 10 then ChkBuffer

loop

sub ChkBuffer 'Received something
local Checksum$ as string = ""
RcvData$ = ""
RxdMsg$ = ""
pause 250 'Time to stack bytes in buffer
If Debug then print "Bytes in Buffer = " str$(loc(#1))
do
RcvData$ = RcvData$ + input$(1, #1) 'Get one byte from buffer
if right$(RcvData$, 1) = STX$ then 'Detected Start Byte
If Debug then print "Startbyte Detected"
exit do
endif
if len(RcvData$) > MaxMsgLength then 'No Start Byte detected
InvalidMsgFlag = 1
exit sub
endif
loop
RcvData$ = ""
Do
RcvData$ = RcvData$ + INPUT$(1, #1) 'Increase D$ by one byte from buffer
IF right$(RcvData$, 1) = ETX$ THEN 'Detected End Byte
If Debug then print "Endbyte Detected"
if Debug then print "Message Length = " +str$(len(RcvData$))
if len(RcvData$) < 2 then 'Detected Start and End but message corrupt
InvalidMsgFlag = 4
exit sub
endif
exit do
endif
if len(RcvData$) > MaxMsgLength then
InvalidMsgFlag = 2 'No End Byte detected
Exit Sub
endif
Loop
RcvData$ = left$(RcvData$, len(RcvData$) - 1) 'Strip End Byte
Checksum$ = right$(RcvData$, 1) 'Get Checksum
RxdMsg$ = left$(RcvData$, len(RcvData$) - 1) 'Strip Checksum
if Checksum$ = Chksum(RxdMsg$) then 'Checksums match
ValidMsgFlag = 1 'We have a good message
exit sub
else
InvalidMsgFlag = 3 'Checksums don't match
endif
end sub

sub PrintMessage
Print "Message Received:- " + RxdMsg$
ValidMsgFlag = 0
end sub

sub InvalidMessage
Select case InvalidMsgFlag
case 1
If Debug then print "***No Start Byte Found***"
Case 2
if Debug then print "***No End Byte Found***"
case 3
if Debug then print "***Checksum Failed***"
case 4
if Debug then Print "***Incorrect Message Length***"
END SELECT
InvalidMsgFlag = 0
end sub

function Chksum(message$) as string 'Creates Checksum of the received Message
local c as integer = 0
local b as integer = 0
local i as integer = len(message$)
local a$ as string
do while (i) > 0
a$ = "&b" + bin$(asc(mid$(message$, i, 1)))
c = val(a$)
b = b xor c
i=i-1
loop
Chksum = chr$(b)
end function