'PIO WS2812 driver on GP0
'
' The PIO program -------------------------------------------------------------

'Set GPIO to GP0, PIO no. 1
SetPin gp0,pio1

'configure the PIO sequencer clock and pin registers
e0=Pio(execctrl GP0,1,4)
p0=Pio(pinctrl 1,1,,,gp0,gp0,)    'GP0 side set, GP0 SET (for pindirs)
f0=Pio(shiftctrl 0,0,0,1)         'Set Auto Pull at 32bits (0)
fr0=5000000                       '5MHz PIO frequency, lowest I could go with my pixels

'This code relies on AutoPull when all 32 bits have been read from X
'line   Bin             code                              comment
'0  1110 0000 1000 0001 'set GP0 output, side(0),         'note GP0 is assigned in pinctrl
'.wrap_target
'1  0110 0002 0010 0001 'out x, 1bit, side(0), dly 1 or 2 or 1 'put one bit in x side set 0
'2  0001 0001 0010 0011 'jmp !x to 4, side(1), dly 1 or 1 or 1 'jump if not X (ie 0) side set 1
'3  0001 0004 0000 0000 'jmp to 1, side(1),    dly 1 or 1 or 2 'jump to 1 side set 1
'4  1010 0004 0100 0010 'MOV Y to Y side(0),   dly 1 or 2 or 2 'Nop delay side set 0
'wrap
PIO program line 1,0,&hEF81
PIO program line 1,1,&h6121
PIO program line 1,2,&h1124
PIO program line 1,3,&h1101
PIO program line 1,4,&hA142

'PIO1.0  setup the machine.
PIO init machine 1,0,fr0,p0,e0,f0,0
'LED data GRBG RBGR BGRB GRBG
Dim Integer ct(3)=(&h00000100,&h00010000,&h01000001,&h00000100)
               
'The MMBasic program --------------------------------------------------------

Do
PIO start 1,0  'start the PIO
For b=0 To 86
PIO WRITE 1,0,3,ct(0),ct(1),ct(2) 'writes led colours to fifo
Next
PIO Write 1,0,1,&h00000000  ' Haven't worked out why I need this to flush?
ct(3)=ct(0):ct(0)=ct(1):ct(1)=ct(2):ct(2)=ct(3) ' rotate the colours
PIO stop 1,0   'stop the pio
Pause 200
Loop While Inkey$=""
End