BME280 for T H & P
HTU21  for T and H
BMP180 for T and P
SHT31  for T H & P
DHT22  for T and H

 ' Dual DS18B20 measuring relative humidity
 ' gp10 is connected to the wet sock DS18B20
 ' gp11 is connected to the ambient temp DS18B20
 
 option default float
 
 ' constants
 e=2.71828172845904
 k1=6.112
 n=0.6687451584
 k2=0.00115
 k3=17.502
 k4=240.97
 
 cls
 box 0,50,320,60,2,rgb(yellow)
 text 15,130,"Data file = B:/rh.csv",,,,rgb(yellow)
 open "b:/rh.csv" for append as #1
 print #1,"date,time,Td,Tw,rH"
 close #1
 w$=""
 av=0
 do
   tempr start gp10,3
   tempr start gp11,3
   pause 900
   av=min(av+1,60)               'running average max 60
   Tw=(tempr(gp10)+(av-1)*Tw)/av 'averaging 60* (1 minute)
   Td=(tempr(gp11)+(av-1)*Td)/av 'averaging 60* (1 minute)
   
   'math from the internet
   ew=k1*e^(k3*Tw/(k4+Tw))
   ed=k1*e^(k3*Td/(k4+Td))
   rH=100*(ew-n*(1+k2*Tw)*(Td-Tw))/ed
   
   'display humidity
   text 16,10,"Room Temp: "+str$(Td,2,4)+" C",,,,rgb(green)
   text 16,30,"Sock Temp: "+str$(Tw,2,4)+" C",,,,rgb(cyan)
   text 16,70,"Humidity: "+str$(rH,3,2)+" %",,,2,rgb(yellow)
   
   if w$<>left$(time$,5) then  'every minute
     w$=left$(time$,5)
     open "b:/rh.csv" for append as #1
     print #1,date$+","+time$+","+str$(Td,2,4)+","+str$(Tw,2,4)+","+str$(rH,3,2)
     close #1
   end if
   pause 100
   
 loop while inkey$=""
end

RUN
16:53:27        20.9    46.2
16:53:37        21.0    45.8
16:53:47        21.0    45.7
16:53:57        20.9    45.8
heater  1
16:54:07        20.9    45.8
16:54:17        22.1    45.9
16:54:27        33.3    20.5
16:54:37        34.2    18.9
16:54:47        34.7    18.4
16:54:57        35.0    17.8
16:55:07        35.3    17.4
16:55:17        35.5    17.2
16:55:27        35.7    17.0
16:55:37        35.9    16.7
16:55:47        36.0    16.5
16:55:57        36.2    16.3
16:56:07        36.3    16.2
16:56:17        36.4    16.1
16:56:27        36.5    16.0
heater  0
16:56:37        36.6    16.0
16:56:47        24.9    32.6
16:56:57        23.7    36.9
16:57:07        23.3    38.1
16:57:17        23.0    38.8
16:57:27        22.7    40.0
16:57:37        22.6    40.5
16:57:47        22.4    41.0
16:57:57        22.3    41.3
16:58:07        22.1    41.7
16:58:17        22.1    42.1
16:58:27        22.0    42.2
16:58:37        21.8    42.2
16:58:47        21.8    42.4
16:58:57        21.8    42.6
16:59:07        21.6    43.2
16:59:17        21.6    43.3
16:59:27        21.5    43.2
16:59:37        21.5    43.2
16:59:47        21.5    43.5
16:59:57        21.4    43.5
17:00:07        21.4    43.9
17:00:17        21.4    44.0

 ' HDC3022 TassyJim Feb 2025
 OPTION EXPLICIT
 OPTION DEFAULT INTEGER
 OPTION BASE 0
 DIM readnow
 DIM FLOAT mytempr, myhumid
 CONST HDCaddr = &h44
 
 SETPIN GP16, GP17, I2C
 I2C OPEN 400, 100
 SETTICK 10000, readit
 setHDCheater &h005F ' &h9F = quarter power
 DO
   IF readnow THEN readHDC3022
   IF INKEY$ = "1" THEN HDCheater 1
   IF INKEY$ = "0" THEN HDCheater 0
 LOOP
 I2C CLOSE
 
SUB readit
 readnow = 1
END SUB
 
SUB readHDC3022
 LOCAL hdc%(6)
 readnow = 0
 I2C WRITE HDCaddr, 0, 2, &h24, &h0B
 PAUSE 15
 I2C READ HDCaddr, 0, 6, hdc%()
 mytempr = 175*(hdc%(0)*256+hdc%(1))/(2^16-1)-45
 myhumid = 100*( hdc%(3)*256+hdc%(4))/(2^16-1)
 PRINT TIME$, STR$(mytempr,3,1),STR$(myhumid,3,1)
END SUB
 
 ' 1 = heater on, 0 = heater off
SUB HDCheater state
 IF state THEN
   I2C WRITE HDCaddr, 1, 2, &h30, &h6D
 ELSE
   I2C WRITE HDCaddr, 1, 2, &h30, &h66
 ENDIF
 PRINT "heater ";state
END SUB
 
SUB setHDCheater heat
 LOCAL crc%, htr%(2)
 IF heat > &h3FFF THEN heat = &h3FFF
 IF heat < 0 THEN heat = 0
 htr%(0) = heat >> 8
 htr%(1) = heat AND &hFF
 crc% = MATH(crc8 htr%(),2, &h31,&hFF)
 I2C WRITE HDCaddr, 0, 5, &h30, &h6E, htr%(0),htr%(1),crc%
END SUB