' Simple GPS Test Program


' First, a detailed note about my LCD screen and some CONSTants in the code ...
'
' My IPS LCD screen appears to operate using an inverted display methodology.
'
' According to the ILI9341 datasheet, the controller has a pair of commands
' that determine the display's behaviour (i.e., inverted and non-inverted),
' which are as follows:
'
' 20h = Display Inversion OFF
' 21h = Display Inversion ON
'
' Unfortunately, I do not think there is a way in the MM language to issue
' commands directly to these types of intelligent LCD controllers. I tried
' the LCD CMD (and LCD DATA) directives, but did not meet with any success.
' I believe these are intended only for use with 1, 2, and 4 line text LCD
' displays.
'
' So, since there does not appear to be a way to interact directly with the
' ILI9341 controller, and since all of the colours on my IPS screen are
' inverted as a result, I had to develop a kludge. Namely, I define my own
' colour constants based on calculating the inversion of the colour I want.
'
' Without this explanation, I am sure the appearance of these constants in
' the code would be less-than-obvious :-).



' Define a number of common/useful colour constants for use with "inverted"
' ILI9341 display mode

CONST MyBlue = RGB(0,0,128) XOR 16777215
CONST MyGreen = RGB(GREEN) XOR 16777215
CONST MyBlack = RGB(BLACK) XOR 16777215
CONST MyRed = RGB(RED) XOR 16777215
CONST MyCyan = RGB(CYAN) XOR 16777215
CONST MyWhite = RGB(WHITE) XOR 16777215


' T is used to calculate a simple 1 second interval, based on TIMER

DIM T as integer


' P is used as a loop counter for pulsing the LCD Backlight

DIM P as INTEGER


' BL_PWM is used to hold the current LCD Backlight setting

DIM BL_PWM as INTEGER


' GPS_PARAM$ is used to hold any given GPS Parameter (e.g., Lat, Long,
' Speed, etc.), as determined by the built-in GPS function.

DIM GPS_PARAM$ AS STRING


' Ensure that the LCD is clear (black)

CLS MyBlack


' Set the LCD colours to Green on Black

COLOUR MyGreen, MyBlack


' We'll use the usual font, double-size

FONT 1, 2


' Turn on the LCD Backlight at full brilliance

BL_PWM = 100
PWM 2, 250, BL_PWM


' Reset the TIMER, and calculate a 1 second interval.
' Then display the TIMER on the LCD, just as a sanity check.

TIMER = 0
T = TIMER + 999
TEXT 0, 0+(MM.VRES*11/12), STR$(TIMER)


' The GPS module will (ultimately) be hooked up on COM3; so
' open/configure it for that purpose.

OPEN "COM3:115200, 256" AS GPS, -5


' The main loop is designed to run for 60 seconds.
'
' Inside the loop, the GPS function is referenced several times to
' extract various parameters, and display them on the LCD screen.

DO


' If we are at a 1 second interval, calculate the next interval
' and show the current TIMER value on the LCD. This is just for
' sanity check purposes and amusement, as the loop is running.

IF Timer > T THEN
T = TIMER + 999
TEXT 0, 0+(MM.VRES*11/12), str$(TIMER)
END IF


' Initially, I simply used the GPS function, buried directly in
' TEXT commands, to display values on the LCD - as follows:
'
' TEXT 0, 0+(MM.VRES*0/12), "GOOD:" + STR$(GPS(VALID)) + SPC(10)
'
' When the program did not generate expected results, I used a
' time-honoured troubleshooting technique by introducing an
' intermediate variable, and "simplifying" the syntax. Now,
' the result of any given GPS function call is first stuffed
' into a variable (GPS_PARAM$), and the corresponding TEXT call
' then simply references that variable.
'
' Unfortunately, this did not improve the situation. However,
' I have left it like that for now, until the issue is resolved
' (and then I plan on reverting to the "prettier" coding approach).


' Show the status of the GPS VALID parameter. (Note that the text
' label names have been shortened to 4 characters or less, so that
' everything will show on the LCD. After all, this is only a
' little test program.)

GPS_PARAM$ = STR$(GPS(VALID))
TEXT 0, 0+(MM.VRES*0/12), "GOOD:" + GPS_PARAM$ + SPC(10)


' NOTE: At this point, a "real" program would only proceed if
' the GPS data was actually determined to be valid. However,
' for test purposes only, the balance of the GPS functions are
' called regardless.


' Show the status of the GPS DATE parameter.

GPS_PARAM$ = GPS(DATE)
TEXT 0, 0+(MM.VRES*2/12), "DATE:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS TIME parameter.

GPS_PARAM$ = GPS(TIME)
TEXT 0, 0+(MM.VRES*3/12), "TIME:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS LATITUDE parameter.

GPS_PARAM$ = STR$(GPS(LATITUDE))
TEXT 0, 0+(MM.VRES*4/12), " LAT:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS LONGITUDE parameter.

GPS_PARAM$ = STR$(GPS(LONGITUDE))
TEXT 0, 0+(MM.VRES*5/12), "LONG:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS TRACK parameter.

GPS_PARAM$ = STR$(GPS(TRACK))
TEXT 0, 0+(MM.VRES*6/12), " DIR:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS SPEED parameter.

GPS_PARAM$ = STR$(GPS(SPEED))
TEXT 0, 0+(MM.VRES*7/12), " SPD:" + GPS_PARAM$ + SPC(10)


' Show the status of the GPS (# OF) SATELLITES parameter.

GPS_PARAM$ = STR$(GPS(SATELLITES))
TEXT 0, 0+(MM.VRES*9/12), "#SAT:" + GPS_PARAM$ + SPC(10)


' Continue looping until 60 seconds (60,000 ms) has elapsed.

LOOP UNTIL TIMER > 60000


' Close the GPS port; make sure we clean up after ourselves.

CLOSE GPS


' Just a bit of foolish glitz and fanfare, here. We'll show a
' little "DONE!" status message (in white, on a red background)
' at the bottom of the LCD screen, and just to go over the top,
' we'll pulse the LCD Backlight 3 times, too.

TEXT MM.HRes/2, 0+(MM.VRES*11/12), " DONE! ", "CM", 1, 2, MyWhite, MyRed

PAUSE 500

FOR P = 1 TO 3

FOR BL_PWM = 100 TO 20 STEP -1
PWM 2, 250, BL_PWM
PAUSE 4
NEXT BL_PWM

FOR BL_PWM = 20 TO 100
PWM 2, 250, BL_PWM
PAUSE 4
NEXT BL_PWM

NEXT P


' The LCD Backlight should already be up at 100% by this point, but
' it does not hurt to be paranoid. Let's make sure the LCD Backlight
' really is up at full brilliance when we end the program.

BL_PWM = 100
PWM 2, 250, BL_PWM


' That's it, that's all :-).

END