' Micromite Mouse Demo Program
'  written by vegipete
'
' External hardware based on a PIC16F18313 microcontroller
' is used to convert PS2 mouse data to serial data.
' The external hardware can recognize a standard wheel mouse.
' Mouse data is ONLY sent when the mouse changes, to a
' maximum of 20 updates per second.
' The data format is an ASCII string of 16 characters:
' "LMR+000+000+000<\r>"
' L, M & R are the buttons, 1 when pressed, 0 when not
' +000 is the position change for each of x, y and z
' (z is the scroll wheel)
' Depending on the mouse, the displacement could range from
' +255 to -255
' On a mouse with no scroll wheel, those fields are zero.
'
' Note that SOME USB mice work in PS2 mode too and work
' just fine with the external hardware.

CLS
Dim integer mx, my, mz, newmouse
Dim integer mbl, mbm, mbr
Dim mxold, myold As integer
Dim dx, dy As float

Open "com4: 38400,256,mouseint,16" As #2

On error skip   ' allow error on next line
Blit close 1    ' ensure blit buffer is free

Text 150,15, "A Mouse and", "CT", 4
Text 150,40, "A Micromite", "CT", 4

Text 10,70, "With a special bit of",,2
Text 10,90, "interface hardware,",,2
Text 10,110, "both work together",,2
mx = 40 : my = 12
Text mx,130, "S",,2,,RGB(RED) : mx = mx + my
Text mx,130, "P",,2,,RGB(yellow) : mx = mx + my
Text mx,130, "E",,2,,RGB(cyan) : mx = mx + my
Text mx,130, "C",,2,,RGB(blue) : mx = mx + my
Text mx,130, "T",,2,,RGB(magenta) : mx = mx + my
Text mx,130, "A",,2,,RGB(green) : mx = mx + my
Text mx,130, "C",,2,,RGB(brown) : mx = mx + my
Text mx,130, "U",,2,,RGB(green) : mx = mx + my
Text mx,130, "L",,2,,RGB(magenta) : mx = mx + my
Text mx,130, "A",,2,,RGB(blue) : mx = mx + my
Text mx,130, "R",,2,,RGB(cyan) : mx = mx + my
Text mx,130, "L",,2,,RGB(yellow) : mx = mx + my
Text mx,130, "Y",,2,,RGB(RED) : mx = mx + my

mx = MM.HRes/2
my = MM.VRes/2
mz = 33
newmouse = 0

GUI BARGAUGE #1, 300,20,10,200,RGB(GREEN),0,0,200
CtrlVal(#1) = mz
GUI LED #2, "", 110,175,10,RGB(RED)
Text 110,190, "Left", "CT", 1
CtrlVal(#2) = mbl
GUI LED #3, "", 160,175,10,RGB(BLUE)
Text 160,190, "Middle", "CT", 1
CtrlVal(#3) = mbm
GUI LED #4, "", 210,175,10,RGB(GREEN)
Text 210,190, "Right", "CT", 1
CtrlVal(#4) = mbr

CursorOn

Do
 If newmouse Then
   'The screen should not be updated while the cursor is displayed
   CursorOff
   CtrlVal(#1) = mz
   CtrlVal(#2) = mbl
   CtrlVal(#3) = mbm
   CtrlVal(#4) = mbr
   CursorOn
   newmouse = 0
 EndIf
 Pause 25
Loop

End

' Routine called when a new data string is received from the mouse
Sub mouseint
 Local dx,dy,dz
 Local string dm$ length 32
 mbl = Val(Input$(1,#2))     ' left button
 mbm = Val(Input$(1,#2))     ' middle button
 mbr = Val(Input$(1,#2))     ' right button
 dx = Val(Input$(4,#2))      ' x movement
 dy = Val(Input$(4,#2))      ' y movement
 dz = Val(Input$(4,#2))      ' z (wheel) movement
 dm$ = Input$(8,#2)          ' read any left over junk

 mx = mx + dx
 If mx < 0 Then mx = 0
 If mx > MM.HRes-2 Then mx = MM.HRes-2
 my = my - dy
 If my < 0 Then my = 0
 If my > MM.VRes-24 Then my = MM.VRes-24
 'Note: can't go to bottom of screen because of bug in text command
 mz = mz + dz
 If mz < 0 Then mz = 0
 If mz > 200 Then mz = 200

 newmouse = 1
End Sub

' Move cursor to (new) mx,my
Sub CursorMove
 CursorOff
 CursorOn
End Sub

' Save screen and paint cursor at mx,my
Sub CursorOn
 Blit read 1,mx,my,14,20   ' save background
 mxold = mx : myold = my   ' save location of saved background
 Text mx,my," ",,10,,,-1   ' paint the cursor
End Sub

' Remove the cursor from the screen and restore screen
Sub CursorOff
 Blit write 1,mxold,myold,14,20  ' restore background
 On error skip   ' allow error on next line
 Blit close 1    ' free up the blit buffer for next time
End Sub

' CursorFont20x24
DefineFont #10
 04201814 00040000 05006000 00480000 42004004 00100400 04048040 04204000
 08400001 44800F04 00A40480 12064052 00200100 0000000C 00000000 00000000
 30000000 00800400 80040048 04004800 C04900E0 49009304 44927428 004424C0
 10040042 04004100 80400008 80000408 01020840 03102000 000000FF FF070000
 070140F0 0220F0FF 20200002 202A0202 88004411 00100480 10040022 10808800
 20000204 2A024221 07522520 0140F0FF 00F0FF07 00000000 FF070000 070140F0
 0220F0FF 20200002 202A0202 88004411 00100480 10040022 10808800 20000204
 2A024221 07522520 0140F0FF 00F0FF07 00000000 00000000
End DefineFont
>