Option explicit
Option default none
option y_axis up
Option console serial
Const stepdef=4
Dim integer i, x=1, y=160, stepsize=stepdef, last_one_gone, update
Dim float current_angle=90
Dim integer showing(64)
Mode 2,16,0,frameint
Pause 3000
Page write 1
CLS

Box 401,1,18,48,2,RGB(green),RGB(Magenta)
Box 421,1,18,48,2,RGB(red),RGB(cyan)
Box 441,1,18,48,2,RGB(yellow),RGB(blue)
Box 461,1,18,48,2,RGB(white),RGB(red)
Box 481,1,18,48,2,RGB(Magenta),RGB(GREEN)
Play modfile "cartoon"
'for i=0 to 7
SPRITE read 10+i,401,1,18,48
SPRITE read 18+i,421,1,18,48
SPRITE read 26+i,441,1,18,48
SPRITE read 34+i,461,1,18,48
SPRITE read 42+i,481,1,18,48
SPRITE copy 10,11,7
SPRITE copy 18,19,7
SPRITE copy 26,27,7
SPRITE copy 34,35,7
SPRITE copy 42,43,7

Load bmp "court"
'CLS
For i=0 To 7
SPRITE show 10+i,401,i*50,1
showing(10+i)=1
SPRITE show 18+i,421,i*50,1
showing(18+i)=1
SPRITE show 26+i,441,i*50,1
showing(26+i)=1
SPRITE show 34+i,461,i*50,1
showing(34+i)=1
SPRITE show 42+i,481,i*50,1
showing(42+i)=1

Next i
SPRITE loadpng 1,"ball"
vector 0,current_angle,0,x,y
SPRITE show 1,x,y,1
update=1
page copy 1 to 0
Do
Loop Until update=0
SPRITE INTERRUPT  collision
Do
 vector 0,current_angle,stepsize,x,y
 SPRITE show 1,x,y,1
 update=1
 Do
 Loop Until update=0
Loop Until last_one_gone
Pause 2000
Play stop
SPRITE close all
Mode 2,8 'disable the interrupt'
Option console both
End

Sub frameint
 If update Then Page copy 1 To 0
 update =0
End Sub

Sub vector(obj As integer, angle As float, distance As float, x_new As integer, y_new As integer)
 Static float y_move(9), x_move(9)
 Static float x_last(9), y_last(9)
 Static float last_angle(9)
 If distance=0 Then
   x_last(obj)=x_new
   y_last(obj)=y_new
 EndIf
 If angle<>last_angle(obj) Then
   y_move(obj)=-Cos(Rad(angle))
   x_move(obj)=Sin(Rad(angle))
   last_angle(obj)=angle
 EndIf
 x_last(obj) = x_last(obj) + distance * x_move(obj)
 y_last(obj) = y_last(obj) + distance * y_move(obj)
 x_new=Cint(x_last(obj))
 y_new=Cint(y_last(obj))
Return


Sub collision
 Local integer i
' First use the SPRITE(S) function to see what caused the interrupt
 If sprite(S) <> 0 Then 'collision of specific individual sprite
   'sprite(S) returns the sprite that moved to cause the collision
'print "Collision on sprite ",sprite(S)
    process_collision(sprite(S))
'     print ""
'
 Else '0 means collision of one or more sprites caused by background move
   ' SPRITE(C, 0) will tell us how many sprites had a collision
'    print "Scroll caused a total of ",sprite(C,0)," sprites to have collisions"
   For i=1 To sprite(C,0)
' SPRITE(C, 0, i) will tell us the sprite number of the Ith sprite
'      print "Sprite ",sprite(C,0,i)
     process_collision(sprite(C,0,i))
   Next i
'    print ""
 EndIf
End Sub
' get details of the specific collisions for a given sprite
Sub process_collision(S As integer)
 Local integer i ,j, k, m
 'sprite(C, #n) returns the number of current collisions for sprite n
'print "Total of ",sprite(C,S)," collisions"
'print SPRITE(C, S, 1)' will tell us the sprite number of the Ith sprite
   For i=1 To sprite(C,S)
   If k Then Exit For
   j=sprite(C,S,i)
   If j=&HF1 Then
     'collision with left of screen
     current_angle=360-current_angle+(Rnd-0.5)*20
     Do While (current_angle>=180 And current_angle<=359) Or current_angle=0
       current_angle=current_angle+(Rnd-0.5)*20
     Loop
   Else If j=&HF2 Then
     'collision with top of screen
       current_angle=((540-current_angle) Mod 360) +(Rnd-0.5)*20
     Do While current_angle<=90 Or current_angle>=270
       current_angle=current_angle+(Rnd-0.5)*20
     Loop
   Else If j=&HF4 Then
     'collision with right of screen
     current_angle=360-current_angle+(Rnd-0.5)*20
     Do While current_angle>=0 And current_angle<=180
       current_angle=current_angle+(Rnd-0.5)*20
     Loop
   Else If j=&HF8 Then
     'collision with bottom of screen
     current_angle=((540-current_angle) Mod 360) +(Rnd-0.5)*20
     Do While current_angle>=90 And current_angle<=270
       current_angle=current_angle+(Rnd-0.5)*20
     Loop
   Else If j=&HF3 Or j= &Hf6 Or j=&Hf9 Or j=&HfC Then
     current_angle = current_angle+180
   Else
     current_angle=360-current_angle+(Rnd-0.5)*20
     If s=1 Then
       vector 0,current_angle,stepsize,x,y
'        SPRITE hide 1
       SPRITE hide safe j:showing(j)=0

'        SPRITE show 1,x,y,1
       Play effect "gunshot"
       m=0
       For k=10 To 49
         If showing(k) Then m=m+1
       Next k
       If m=0 Then
         last_one_gone=1
       EndIf
       Page copy 1 To 0
     EndIf
   EndIf
 Next i
End Sub