CPU Sleep 60

CPU Sleep 60,16

' CMM2 RTC alarm clock - TassyJim
 OPTION AUTORUN ON
 DIM RTCbuff(20)
 DIM RTCaddr = &h68
 DIM RTCtime$, RTCdate$
 CLS
 PRINT "MM  Time = ";TIME$;"   ";DATE$;"   ";dow$(doweek(DATE$))
 PRINT
 DO
   PRINT
   PRINT "1   Set RTC"
   PRINT "2   Read RTC"
   PRINT "3   Set MM from RTC"
   PRINT "4   Input alarm times"
   PRINT "5   Arm alarms"
   PRINT "6   Clear alarm"
   PRINT
   PRINT "Choice?"
   DO
     c$ = INKEY$
   LOOP UNTIL c$ <>""
   IF c$ = "1" THEN setRTC
   IF c$ = "2" THEN showAll
   IF c$ = "3" THEN showAll : setMM
   IF c$ = "4" THEN doSetAlarm
   IF c$ = "5" THEN doArmAlarm
   IF c$ = "6" THEN clearAlarm
 LOOP
 
SUB showAll
 readRTC
 getRTC
 PRINT "RTC Time = ";RTCtime$;"   ";RTCdate$;"   ";dow$(doweek(RTCdate$))
 PRINT "MM  Time = ";TIME$;"   ";DATE$;"   ";dow$(doweek(DATE$))
 PRINT
 AL1$ = getAlarm$(1)
 AL2$ = getAlarm$(2)
 PRINT "Alarm 1 ";AL1$
 PRINT "Alarm 2 ";AL2$
 control$ = BIN$(RTCbuff(14),8)
 PRINT "Control ";control$
 status$ = BIN$(RTCbuff(15),8)
 PRINT "Status  ";status$
END SUB
 
SUB setRTC ' set RTC to MM time
 LOCAL INTEGER BCDh, BCDm, BCDs, BCDd, BCDmo, BCDy, BCDw
 LOCAL now$, today$
 now$=TIME$
 today$=DATE$
 BCDh  = VAL("&H"+LEFT$(now$, 2))
 BCDm  = VAL("&H"+MID$(now$, 4, 2))
 BCDs  = VAL("&H"+MID$(now$, 7,2))
 BCDd  = VAL("&H"+LEFT$(today$, 2))
 BCDmo = VAL("&H"+MID$(today$, 4, 2))
 BCDy  = VAL("&H"+RIGHT$(today$, 2))
 BCDw  = doweek(today$)
 
 ' Write Time to RTC
 I2C3 OPEN 100,100' Enable I2C
 I2C3 WRITE RTCaddr, 0, 8,0, BCDs, BCDm, BCDh, BCDw, BCDd, BCDmo, BCDy
 I2C3 CLOSE
 PRINT "0=ok 1=nack 2=timeout   "; MM.I2C
 PRINT "RTC set to: ";now$;"   ";today$
 PRINT
END SUB
 
SUB readRTC
 I2C3 OPEN 100, 200 ' Enable I2C
 I2C3 WRITE RTCaddr, 0, 1, 0
 I2C3 READ RTCaddr, 0, 19, RTCbuff(0)
 I2C3 CLOSE
END SUB
 
SUB getRTC
 LOCAL RTCsec$,RTCmin$,RTChr$,RTCwday$,RTCday$,RTCmon$,RTCyr$
 RTCsec$ =HEX$((RTCbuff(0) AND &H7F),2)
 RTCmin$ =HEX$((RTCbuff(1) AND &H7F),2)
 RTChr$  =HEX$((RTCbuff(2) AND &H3F),2)
 RTCwday$=HEX$((RTCbuff(3) AND &H07),2)
 RTCday$ =HEX$((RTCbuff(4) AND &H3F),2)
 RTCmon$ =HEX$((RTCbuff(5) AND &H1F),2)
 RTCyr$  ="20"+HEX$((RTCbuff(6)),2)
 RTCtime$=RTChr$+":"+RTCmin$+":"+RTCsec$
 RTCdate$=RTCday$+"-"+RTCmon$+"-"+RTCyr$
 
END SUB
 
SUB setMM
 TIME$=RTCtime$
 DATE$=RTCdate$
 PRINT "MM Time set!"
END SUB
 
FUNCTION getAlarm$( n)
 LOCAL ALsec$,ALmin$,ALhr$,ALwd$
 IF n = 1 THEN
   ALsec$ =HEX$((RTCbuff(7) AND &H7F),2)
   ALmin$ =HEX$((RTCbuff(8) AND &H7F),2)
   ALhr$  =HEX$((RTCbuff(9) AND &H3F),2)
   ALwd$  =HEX$((RTCbuff(10) AND &H3F),2)
   ALmode$=STR$(bit(RTCbuff(10),6))+STR$(bit(RTCbuff(7),7))+STR$(bit(RTCbuff(8),7))+STR$(bit(RTCbuff(9),7))
   ALMode$ = ALmode$+STR$(bit(RTCbuff(14),0))+STR$(bit(RTCbuff(15),0))
 ELSE
   ALsec$ = "00"
   ALmin$ =HEX$((RTCbuff(11) AND &H7F),2)
   ALhr$  =HEX$((RTCbuff(12) AND &H3F),2)
   ALwd$  =HEX$((RTCbuff(13) AND &H3F),2)
   ALmode$=STR$(bit(RTCbuff(13),6))+STR$(bit(RTCbuff(11),7))+STR$(bit(RTCbuff(12),7))+"0"
   ALMode$ = ALmode$+STR$(bit(RTCbuff(14),1))+STR$(bit(RTCbuff(15),1))
 ENDIF
 
 getAlarm$=ALhr$+":"+ALmin$+":"+ALsec$+"-"+ALwday$+"-"+ALmode$
END FUNCTION
 
SUB doSetAlarm
 LOCAL at1$, at2$
 INPUT "Alarm Time 1 ",at1$
 INPUT "Alarm Time 2 ",at2$
 IF at1$ <>"" THEN setAlarm(at1$,1)
 IF at2$ <>"" THEN setAlarm(at2$,2)
END SUB
 
SUB setAlarm(atime$, n)
 LOCAL INTEGER BCDh, BCDm, BCDs, BCDd
 BCDh  = VAL("&H"+LEFT$(atime$, 2))
 BCDm  = VAL("&H"+MID$(atime$, 4, 2))
 BCDs  = VAL("&H"+MID$(atime$, 7,2))
 BCDd  = VAL("&H"+MID$(atime$, 10,2)) OR &b10000000 ' hours and minutes match
 I2C3 OPEN 100,100' Enable I2C
 IF n = 1 THEN
   I2C3 WRITE RTCaddr, 0, 5,7, BCDs, BCDm, BCDh, BCDd
 ELSE
   I2C3 WRITE RTCaddr, 0, 4,11, BCDm, BCDh, BCDd
 ENDIF
 I2C3 CLOSE
END SUB
 
SUB doArmAlarm
 LOCAL al
 INPUT "alarm to arm ", al
 armAlarm(al)
END SUB
 
SUB armAlarm n
 LOCAL alCMD
 readRTC
 '
 SELECT CASE n
   CASE -1 ' disarm alarm 1
     alCMD = RTCbuff(14) AND &b11111110
   CASE 1  ' arm alarm 1
     alCMD = RTCbuff(14)  OR &b00000001
   CASE -2 ' disarm alarm 2
     alCMD = RTCbuff(14) AND &b11111101
   CASE 2  'arm alarm 2
     alCMD = RTCbuff(14)  OR &b00000010
 END SELECT
 I2C3 OPEN 100,100
 I2C3 WRITE RTCaddr, 0, 2,14,alCMD
 i2c3 CLOSE
END SUB
 '
SUB clearAlarm
 alCMD = RTCbuff(15) AND &b11111100
 I2C3 OPEN 100,100
 I2C3 WRITE RTCaddr, 0, 2,15,alCMD
 i2c3 CLOSE
 PRINT "alarm state cleared ";BIN$(alCMD,8)
END SUB
 
FUNCTION doweek(theDate$) AS INTEGER
 LOCAL INTEGER dy, month, year, dayofyear, dayz
 dy = VAL(LEFT$(theDate$, 2))
 month = VAL(MID$(theDate$, 4, 2))
 year = VAL(RIGHT$(theDate$, 4))
 dayofyear= dy+INT((month-1)*30.57+0.5)
 IF month >2 THEN
   dayofyear= dayofyear-1
   IF (year/4)>0 THEN dayofyear= dayofyear-1
 ENDIF
 dayz= INT((year-1900)*365.25)+dayofyear+1
 doweek= dayz-1-INT((dayz-1)/7)*7
END FUNCTION
 
FUNCTION dow$(d)
 dow$=MID$("SUNMONTUEWEDTHUFRISATSUN",d*3+1,3)
END FUNCTION
 
FUNCTION checkRTC()
 LOCAL rcvbuf
 'i2caddr = &h51 ' PCF8563 I2C address
 'i2caddr = &h68 ' DS1307, DS3231, DS3232
 I2C3 OPEN 100, 200
 PAUSE 20
 I2C3 READ RTCaddr, 0,1, rcvbuf
 PRINT "checking DSxxxx";MM.I2C
 I2C3 CLOSE
 checkRTC = MM.I2C
END FUNCTION
 
FUNCTION bit(n AS INTEGER,b AS INTEGER) AS INTEGER
 ' return value of bit b (0 - 63) of n
 bit = (n >> b) AND 1
END FUNCTION
 
FUNCTION setBit(n AS INTEGER,b AS INTEGER) AS INTEGER
 setBit = n OR (1 << b)
END FUNCTION
 
FUNCTION clearBit(n AS INTEGER,b AS INTEGER) AS INTEGER
 clearBit = n AND INV(1 << b)
END FUNCTION