'PICO 2 HDMI only
'Reads and shows 4 Bit uncompressed BMP Files in up to 640x480 resolution
' and sets the Colors using the MAP Command
Data "kingtut.bmp","W95Beta.bmp","koeln_4bit.bmp","end"
MODE 2
Map reset:Map set
CLS
Dim integer w,h,hi,f,cl,c,scr,xr2
Do
 Read File$:If file$="end" Then Exit Do
 Map reset
 Open file$ For input As #1
 read_BMP_Header
 Map set
 MODE 2+(h>240)
 hi=MM.VRES
 xr2=MM.HRES/2
 scr=MM.Info(WRITEBUFF)
 yofs=(hi-h)/2
 yofs=hi-yofs
 Seek #1,of+1
 For y=yofs To (yofs-h)+1 Step -1
 ss=scr+(y*xr2)
 For x=0 To w-1 Step 2
   c=Asc(Input$(1,1))
   c=(c<<4)+(c>>4):Poke byte ss+(x/2),c
   Next
 Next
 Close #1
 Pause 5000
Loop

Sub read_BMP_Header
 Local l$
 WStart= &H13
 Hstart= &H17
 MPStart= 55
 'read offset of Picture data
 Seek #1,11
 l$=Input$(1,1):of=Asc(l$)
 l$=Input$(1,1):Inc of,256*(Asc(l$))
 'read Picture width
 Seek #1,WStart
 l$=Input$(1,1):W=Asc(l$)
 l$=Input$(1,1):Inc w,256*(Asc(l$))
 'read Picture height
 Seek #1,HStart
 l$=Input$(1,1):h=Asc(l$)
 l$=Input$(1,1):Inc h,256*(Asc(l$))

 'write the Color data to Map
 Seek #1,MPStart
 For F=0 To 15
   l$=Input$(1,1):B=Asc(l$)
   l$=Input$(1,1):G=Asc(l$)
   l$=Input$(1,1):R=Asc(l$)
   l$=Input$(1,1)'fillbyte
   Map(f)=RGB(R,G,B)
 Next
End Sub

For y=yofs To yofs-h-2 Step -1
  For x=0 To w-1 Step 2
    c=asc(Input$(1,1))
    Pixel x,y,Map(c>>4):Pixel x+1,y,Map(c And 15)
  Next
Next