HUMID 3, temp, humid
pause 3000 'wait 3 seconds before doing a second reading
HUMID 3, temp, humid
open "com1:9600" as #1
open "com2:9600" as #2
Do:Loop until LOC(#1)<>0 'Wait for pressure data
P$=Input$(LOC(#1),#1) 'Save whatever is in COM1 buffer to P$
pressureValue=asc(P$) 'Convert data to number
Pressure = ((pressureValue/1024.0)+0.095)/0.000009
Print #2,"The pressure is: "; Pressure
print #2,"The temperature is " temp " and the humidity is " humid
close #2
close #1

SetPin 23,AIN 'Configure pin23 for analog input
HUMID 3, temp, humid 'Sensor on pin 3
pause 3000 'wait 3 seconds before doing a second reading
HUMID 3, temp, humid
open "com2:9600" as #2
Pressure = ((Pin(23)/1024.0)+0.095)/0.000009
Print #2,"The pressure is: "; Pressure
print #2,"The temperature is " temp " and the humidity is " humid
close #2

' reading the BMP085 pressure and DHT22 humidity sensors
' TassyJim 28 Oct 2014

OPTION clocktrim -4
DHT22pin = 26 ' 3.3V pins are OK for short leads <1 metre

DIM BMPData(2) ' store data from BMP085
DIM cal(11) ' calibration data
oss = 0 ' over sampling 0 to 3
alt = 240 ' your altitude in metres

BMP085calMEM = &HAA ' start of 11 calibration values
BMP085address = &H77 ' BMP085 address
BMP085control = &HF4 ' BMP085 control register
BMP085temp = &H2E ' BMP085 temperature command
BMP085pres = &H34 ' BMP085 pressure command
BMP085pres = BMP085pres + oss*&H40 ' adjust command for oversampling
BMP085reading = &HF6 ' register for results of reading

I2C OPEN 400, 200 ' Enable I2C. use slow speeds for long leads
PAUSE 20
z = Calibrate() ' read the calibration data
SETTICK 10000, doread
PAUSE 1000
doread

DO
LOOP
END

SUB doread
readhumidity
t=temperature()
p=pressure(oss)
p0=Psl(p,alt)
PRINT TIME$;" T(BMP085):";STR$(t,3,1);" P(sl):";STR$(p0/100,5,1);
PRINT " T(DHT22): " STR$(TEMP,3,1);" H:" STR$(HUMID,3,1)
'PAUSE (30000) ' delay 30 seconds between readings
END SUB

FUNCTION Calibrate()
' needs to be called once for each module.
' safest to do it on every program start.
LOCAL n, calMEM
calMEM= BMP085calMEM
FOR n = 1 TO 11
I2C WRITE BMP085address, 0, 1, calMEM ' first calibration location
PAUSE 1
I2C READ BMP085address, 0, 2, BMPData(0)
'print BMPData(1), BMPData(0)*256 + BMPData(1)
cal(n) = BMPData(0)*256 + BMPData(1)
IF n < 4 OR n > 6 THEN ' need to convert some to signed numbers
IF cal(n) > 32767 THEN
cal(n) = cal(n) - 65536
ENDIF
ENDIF
'print n,cal(n)
PAUSE 1
calMEM=calMEM+2 ' advance to the next calibration location
NEXT n
END FUNCTION

FUNCTION temperature()
' returns the temperature in degrees C to one decimal place
LOCAL UT, x1, x2, b5
I2C WRITE BMP085address, 0, 2, BMP085control, BMP085temp
PAUSE 5
I2C WRITE BMP085address, 0, 1, BMP085reading
I2C READ BMP085address, 0, 2, BMPData(0)
UT = BMPData(0)*256 + BMPData(1)
'calculate true temperature
x1= INT( (UT-cal(6))*cal(5)/32768)
x2=INT( cal(10)*2048/(x1+cal(11)))
b5=x1+x2
temperature = INT((b5+8)/16)/10
END FUNCTION

FUNCTION pressure(oss)
' returns the pressure in pascals. Divide by 100 for millibars
' recalculates the temperatre.
' time could be saved by reading the temperature once evry 10 minutes
' when taking readings at short intervals
LOCAL UT, UP, x1, x2, x3, b5, b6, b7, pres, p
pres = BMP085pres + oss*&H40
I2C WRITE BMP085address, 0, 2, BMP085control, BMP085temp
PAUSE 5
I2C WRITE BMP085address, 0, 1, BMP085reading
I2C READ BMP085address, 0, 2, BMPData(0)
UT = BMPData(0)*256 + BMPData(1)
I2C WRITE BMP085address, 0, 2, BMP085control, pres
IF oss = 0 THEN ' different oversampling requires different
PAUSE 5 ' reading times
ELSEIF oss = 1 THEN
PAUSE 8
ELSEIF oss = 2 THEN
PAUSE 14
ELSE
PAUSE 26
ENDIF
I2C WRITE BMP085address, 0, 1, BMP085reading
I2C READ BMP085address, 0, 2, BMPData(0)
UP = BMPData(0)*256 + BMPData(1)
I2C WRITE BMP085address, 0, 1, BMP085reading+2
I2C READ BMP085address, 0, 1, BMPData(0)
UP=(UP*256+BMPData(0))/2^(8-oss)
'calculate true temperature
x1= INT( (UT-cal(6))*cal(5)/32768)
x2=INT( cal(10)*2048/(x1+cal(11)))
b5=x1+x2
t=INT((b5+8)/16)/10
'print "Temperature: ",t
'calculate true atmospheric pressure
b6 = b5 - 4000
x1 = INT((cal(8)*(b6*b6/4096))/2048)
x2 = INT(cal(2)*b6/2048)
x3 = x1 + x2
b3 = INT(((cal(1)*4+x3)*2^oss +2)/4)
x1 = INT(cal(3)*b6/8192)
x2 = INT((cal(7)*(b6*b6/4096))/65536)
x3 = INT(((x1+x2)+2)/4)
b4 = INT(cal(4)*x3/32768+cal(4))
b7 = INT((UP - b3)*(50000/2^oss))
p = INT((b7*2)/b4)
x1 = INT(INT(p/256)*INT(p/256))
x1 = INT((x1*3038)/65536)
x2 = INT((-7357*p)/65536)
pressure = INT(p+(x1 + x2 + 3791)/16)
END FUNCTION

FUNCTION Psl(p, alt)
'given local pressure and altitude, returns pressure at sea level
Psl= p/(1- alt/44330.77)^5.25588
END FUNCTION

FUNCTION myAlt(p, p0)
' given local pressure (p) and pressure at sea level (p0)
' returns altitude in metres
myAlt = 44330.77*(1-(p/p0)^0.190263)
END FUNCTION

SUB readhumidity
DHT22 DHT22pin, TEMP, HUMID ' dump stale reading
PAUSE 2000 ' time for the sensor to complete next read
DHT22 DHT22pin, TEMP, HUMID ' this reading is only 2 seconds old
'PRINT TIME$;" Temperature: " STR$(TEMP,3,1);" Humidity: " STR$(HUMID,3,1)
END SUB