' get led-data from bmp-file
' 11  4 byte offBits
' 19  4 byte biWidth
' 23  4 byte biHeight
Option DEFAULT NONE
Option EXPLICIT

Dim Integer tmp(8) 'Dim Leds follows later when size is known
Dim Integer lAdr,tAdr
Dim Integer offBits,biWidth,biHeight
Dim Integer x,y,fill,mCnt,lCnt

' sys-init
SetPin GP0, DOUT       'outputpin for the first  ws2812-matrix

'Drive "B:"
Open "MPTeaCup.bmp" For random As #1
 '- read parts of bmp-header
 Seek #1,11                'skip type("BM"),size,reserved
  offBits  = ReadDWord()
 Seek #1,19                'skip headersize
  biWidth  = ReadDWord()
  biHeight = ReadDWord()
 '- read bmp-data
 Dim Integer Leds(biWidth*biHeight) 'Array for bmp-data
 Seek #1,offBits+1         'skip planes, bitcount, compress, ...
 For y = 0 To biHeight-1
   For x = 0 To biWidth-1
     Leds((x*biHeight)+y)= ReadPixel() '3 bytes BGR-values divided by 8
   Next x
   fill = 3-Loc(#1)And 3   'mask last 2 bit to fill up to 4-byte boundary/line
   If fill>0 Then = Asc(Input$(fill,#1)) 'skip dummy-data
 Next y
Close #1

lAdr = Peek(VarAddr Leds()) 'adr of led-data
tAdr = Peek(VarAddr tmp())  'adr of temp-data

mCnt = biWidth*8            'in pixel
If mCnt>256 Then lCnt=256 Else lCnt=mCnt    'max Ws2812 bitbang
'- main loop -----------------------------------------------------
Do
 Device WS2812 B, GP0, lCnt, Leds()        'sys-function
 Memory Copy Integer lAdr,tAdr,8           'copy 1 column(8pix) to temp buffer
 Memory Copy Integer lAdr+(64),lAdr,mCnt-8 'move all from second to last column
 Memory Copy Integer tAdr,lAdr+(mCnt-8)*8,8'copy temp buffer in last column
 Pause 60
Loop

'- functions ------------------------------------------------------
Function ReadPixel() As Integer
Local integer Bl,Gr,Re
 Bl=Asc(Input$(1,#1))>>3
 Gr=Asc(Input$(1,#1))>>3
 Re=Asc(Input$(1,#1))>>3
 ReadPixel = (Re<<16)+(Gr<<8)+Bl
End Function

Function ReadDWord() As Integer
Local integer lsb,msb,msb1,msb2
 lsb =Asc(Input$(1,#1))
 msb =Asc(Input$(1,#1))
 msb1=Asc(Input$(1,#1))
 msb2=Asc(Input$(1,#1))
 ReadDWord = (msb2<<24)+(msb1<<16)+(msb<<8)+lsb
End Function