' test ADC burst read and fft
' connect ADC input to PWM output using RC filter to create triangle-ish wave
' PWM = 400Hz
' ADC takes 512 samples for fft, sampling 10 cycles

pwm_freq = 400
samples = 511
adc_freq = pwm_freq*samples/10 '10 cycles
gain = MM.VRes/(3.3*2)         'waveform gain
'fftgn = MM.VRes/(3.3*samples) 'fft gain in linear mode

'reserve memory
Dim array!(samples),fftarr!(samples)

'open PWM(GP18) and ADC(GP26)
SetPin GP18,pwm1A
SetPin GP26,ain
ADC open adc_freq, 1, ready_int

'start PWM
PWM 1,pwm_freq,50   ' 50% = square wave
Pause 100

'start ADC
ADC start array!()

Do :Loop
End

'when all samples are measured we end up here.
Sub ready_int
 ADC close
 CLS

 'plot input waveform
 For i=0 To samples-1
   'Print Str$(array!(i),2,2),
   x=i*MM.HRes/samples
   Line x,gain*array!(i),x+1,gain*array!(i+1),1,RGB(yellow)
 Next i

 'DO FFT
 Math fft magnitude array!(),fftarr!()

 'convert to log
 For i=0 To samples
   fftarr!(i)=20*Log(fftarr!(i))/Log(10)
 Next i
 fftgn = 2  'gain or displaying the fft in the plot window, roughly

 'plot fft waveform
 For i=0 To samples/2
   Print Str$(fftarr!(i),2,2),
   x=i*2*MM.HRes/samples
   Line x,240-fftgn*fftarr!(i),x+1,240-fftgn*fftarr!(i+1),1,RGB(red)
 Next i

 Print "ready"
 End
End Sub