Predefined Read Only Variables:
==============================

MM.INFO(FONTHEIGHT)
MM.INFO(FONTWIDTH)
Integers representing the height and width of the current font (in pixels).

MM.INFO(HPOS)
MM.INFO(VPOS)
The current horizontal and vertical position (in pixels) following the last graphics or print command.

MM.INFO(MODE)
Returns the video mode as a floating point number e.g. 1.8, 2.16, etc.

1 = 800 x 600 pixels
2 = 640 x 400 pixels
3 = 320 x 200 pixels
4 = 480 x 432 pixels
5 = 240 x 216 pixels
6 = 256 x 240 pixels
7 = 320 x 240 pixels
8 = 640 x 480 pixels
9 = 1024 x 768 pixels (12-bit mode not available)
10 = 848 x 480 pixels (widescreen format)
11 = 1280 x 720 pixels (only .8 and .16 bit colour)
12 = 960 x 540 pixels (only .8 and .16 bit colour)

.8 = 8 bit colour
.12 = 12 bit colour
.16 = 16 bit colour

eg. 7.12 is "mode 7, 320x240 pixels, 12 bit colour"

MM.HRES
MM.VRES
Integers representing the horizontal and vertical resolution of the VGA
display in pixels.

Commands:
========

LEN( string$ )
Returns the number of characters in 'string$'.

TEXT x, y, string$ [,alignment$] [, font] [, scale] [, c] [, bc]
Displays a string on the VGA monitor starting at 'x' and 'y'.
‘string$’ is the string to be displayed. Numeric data should be converted to a
string and formatted using the Str$() function.
' alignment$' is a string expression or string variable consisting of 0, 1 or 2
letters where the first letter is the horizontal alignment around 'x' and can be
L, C or R for LEFT, CENTER, RIGHT and the second letter is the vertical
alignment around 'y' and can be T, M or B for TOP, MIDDLE, BOTTOM.
The default alignment is left/top.
A third letter can be used in the alignment string to indicate the rotation of
the text. This can be 'N' for normal orientation, 'V' for vertical text with each
character under the previous running from top to bottom, 'I' the text will be
inverted (ie, upside down), 'U' the text will be rotated counter clockwise by
90º and 'D' the text will be rotated clockwise by 90º
'font' and 'scale' are optional and default to that set by the FONT command.
'c' is the drawing colour and 'bc' is the background colour. They are optional
and default to the current foreground and background colours.
See the chapter "Basic Drawing Commands" for a definition of the colours
and graphics coordinates.

'HerryText.BAS
'Ways To locate the cursor
'Demo by Womble 20 SEPT 2020
'
'

DO
  print "Choose a number between 1 and 12"
  INPUT i
  i = INT(i)
LOOP UNTIL i <= 12
MODE i,8
CLS
'Default COLOUR is WHITE on BLACK
print "Firmware Version = ",MM.INFO(VERSION)
'Print stuff in Yellow on Black
COLOUR RGB(YELLOW),RGB(BLACK)
print "Video Mode ", STR$(MM.INFO(MODE)),
SELECT CASE  INT(MM.INFO(MODE))
  CASE 1
     print " 800x600"
  CASE 2
     print " 640x400"
   CASE 3
     print " 320x200"
  CASE 4
     print " 480x432"
  CASE 5
     print " 240x216"
  CASE 6
     print " 256x240"
  CASE 7
     print " 320x240"
  CASE 8
     print " 640x480"
  CASE 9
     print " 1024x768"
  CASE 10
     print " 848x480"
  CASE 11
     print " 1280x720"
  CASE 12
     print " 960x540"
  CASE ELSE
     print "no idea what mode we are in"
     END   'abort out of program
END SELECT

'change font here to see what happens
print "we are using the DEFAULT font"
'
print "Font Height", STR$(MM.INFO(FONTHEIGHT))
print "Font Width", STR$(MM.INFO(FONTWIDTH))

'Display something in the middle of the screen
'Text alignment is Centre Middle expressed as "CM"
TEXT(MM.HRES/2),(MM.VRES/2),"THE MIDDLE OF THE SCREEN","CM"
'Save the current cursor location
xCursor$ = STR$(MM.INFO(HPOS))
yCursor$ = STR$(MM.INFO(VPOS))
'print a little underline _ cursor in red
COLOUR RGB(RED),RGB(BLACK)
PRINT  "__"
'Display the cursor position centered in the middle of the screen, aligned CENTER TOP "CT"
'on the penultimate line of the screen
DisplayText$ = "Cursor X,Y was at = " + xCursor$ + "," + yCursor$
TEXT(MM.HRES/2),(MM.VRES-((MM.INFO(FONTHEIGHT)*2))),DisplayText$,"CT"
COLOUR RGB(GREEN),RGB(BLACK)
'Exit message 4 lines up
TEXT(MM.HRES/2),(MM.VRES-((MM.INFO(FONTHEIGHT)*4))),"ENTER SOME TEXT TO EXIT","CT"
DO
  INPUT getmeout$
LOOP UNTIL getmeout$ <> ""


END
'program ends here

PRINT@( (MM.INFO(FONTWIDTH)*x),(MM.INFO(FONTHEIGHT)*y) )"";

where x is the character column, and y is the character row