DefineFont #n
 aabbccdd xxxxxxxx ...
End DefineFont

OPTION DEFAULT NONE
OPTION EXPLICIT
OPTION BASE 0

CONST INP.FNT = "AtariST.BMP"   'input file name
CONST OUT.FNT = "AtariST.FNT"   'output file name
CONST CHR_W.FNT = 8             'char width in pixels
CONST CHR_H.FNT = 16            'char height in pixels
CONST BMP_W.FNT = 128           'BMP width in pixels
CONST TOPLEFT.FNT = 32          'first char read from BMP
CONST BOTRIGHT.FNT = 255        'last char read from BMP
CONST FIRST.FNT = 32            'ACII of first char
CONST INVERT.FNT = 1            '0=WHITE on BLACK, 1=BLACK on WHITE (can be used to invert font)

convChar

END
SUB convChar
 LOCAL INTEGER ww = BMP_W.FNT / CHR_W.FNT
 LOCAL INTEGER hh = 32/CHR_W.FNT
 LOCAL INTEGER x, y
 LOCAL INTEGER xx, yy, col, bright, b, ch, cpl = 0
 LOCAL STRING h = ""

 LOAD BMP INP.FNT

 OPEN OUT.FNT FOR OUTPUT AS #1
 ?#1,"DefineFont #8"
 ?#1,"  "HEX$(BOTRIGHT.FNT-TOPLEFT.FNT+1,2)HEX$(FIRST.FNT,2)HEX$(CHR_H.FNT,2)HEX$(CHR_W.FNT,2)
 ?#1,"  ";

 FOR ch =TOPLEFT.FNT TO BOTRIGHT.FNT
   x = (ch MOD ww) * CHR_W.FNT
   y = (ch\ww) * CHR_H.FNT
   FOR yy=0 TO CHR_H.FNT-1
     b = 0
     FOR xx=0 TO CHR_W.FNT-1
       col = PIXEL(x + xx, y + yy)
       bright = ((col AND &hFF0000) >> 16) + ((col AND &hFF00) >> 8) + (col AND &hFF)
       IF INVERT.FNT THEN
         IF bright < 382 THEN
           b = b + 2^(CHR_W.FNT - xx - 1)
           PIXEL x + xx, y + yy, RGB(RED)
         ENDIF
       ELSE
         IF bright > 382 THEN
           b = b + 2^(CHR_W.FNT - xx -1)
           PIXEL x + xx, y + yy, RGB(RED)
         ENDIF
       ENDIF
     NEXT xx
     h = HEX$(b,2) + h
     IF LEN(h) = 8 THEN
       ?#1,h" ";
       h = ""
       cpl = cpl + 1
       IF cpl = 8 THEN
         IF ch < BOTRIGHT.FNT THEN
           ?#1
           ?#1,"  ";
         ENDIF
         cpl = 0
       ENDIF
     ENDIF
   NEXT yy
 NEXT ch
 ?#1
 ?#1,"END DefineFont"
 CLOSE #1
END SUB