'DS18x20 test code by TassyJim
DIM INTEGER PinNbr = 24 ' 22
PRINT
PRINT
PRINT "Family name: ";FamilyName$(PinNbr)
PRINT "Rom Code:    ";getRomCode$(PinNbr)
PRINT "ScratchPad:  ";getScratchpad$(PinNbr)

IF powerMode(PinNbr) THEN
  PRINT "Power mode   External"
ELSE
  PRINT "Power mode   Parasitic"
ENDIF
 
PRINT

print "temp = "; tempr(PinNbr)
FOR n = 9 TO 12
PRINT
  x = setResolution(PinNbr, n)
  PRINT "ScratchPad:  ";getScratchpad$(PinNbr)
  'pause 10000
  TIMER = 0
  PRINT "Temperature: ";getTemp(PinNbr);" ";TIMER;"mS,";n;" bit"
NEXT n

END


FUNCTION getRomCode$(PinNbr AS INTEGER)
' get ROM Code - useful if you want more than 1 device on wire
LOCAL INTEGER a1,a2,a3,a4,a5,a6,a7,a8
ONEWIRE WRITE PinNbr,1,1,&h33 'read ROM code
ONEWIRE READ PinNbr,0,8,a1,a2,a3,a4,a5,a6,a7,a8
getRomCode$ = HEX$(a1,2)+" "+HEX$(a2,2)+" "+HEX$(a3,2)+" "+HEX$(a4,2)+" "+HEX$(a5,2)+" "+HEX$(a6,2)+" "+HEX$(a7,2)+" "+HEX$(a8,2)
END FUNCTION

FUNCTION getScratchpad$(PinNbr AS INTEGER)
'ONEWIRE Write PinNbr,1,9,&h55,a1,a2,a3,a4,a5,a6,a7,a8  'read from scratchpad
ONEWIRE WRITE PinNbr,1,2,&hcc,&hbe
ONEWIRE READ PinNbr,0,8,a,b,c,d,e,f,g,h
getScratchpad$ = HEX$(a,2)+" "+HEX$(b,2)+" "+HEX$(c,2)+" "+HEX$(d,2)+" "+HEX$(e,2)+" "+HEX$(f,2)+" "+HEX$(g,2)+" "+HEX$(h,2)
END FUNCTION

FUNCTION powerMode(PinNbr AS INTEGER) AS INTEGER
' check whether power external (1) or parasitic (0)
ONEWIRE RESET PinNbr
ONEWIRE WRITE PinNbr, 1,2,&hcc, &hb4
ONEWIRE READ PinNbr,4,1,powerMode
END FUNCTION

FUNCTION getFamily(PinNbr AS INTEGER) AS INTEGER
getFamily = VAL("&h"+LEFT$(getRomCode$(PinNbr),2))
END FUNCTION

FUNCTION FamilyName$(PinNbr AS INTEGER)
LOCAL INTEGER fn
fn = getFamily(PinNbr)
SELECT CASE fn
  CASE 16
    FamilyName$ = "DS1820/DS18S20"
  CASE 34
    FamilyName$ = "DS18S22"
  CASE 40
    FamilyName$ = "DS18B20"
  CASE ELSE
    FamilyName$ = "Unknown"
END SELECT
END FUNCTION

FUNCTION setResolution(PinNbr AS INTEGER,r AS INTEGER)
r = r-9
IF r < 0 THEN r = 0
IF r > 3 THEN r = 3
r = r*32+31
ONEWIRE WRITE PinNbr, 1,5,&hcc, &h4E, &hFF,&hFF,r
END FUNCTION

FUNCTION getTemp(PinNbr AS INTEGER) AS FLOAT
LOCAL INTEGER fn, t, T1, T2, a,b,c,d,e,f,g,h
LOCAL FLOAT Value
fn = getFamily(PinNbr)
power = powerMode(PinNbr)
ONEWIRE WRITE PinNbr,1,2,&hcc,&hbe
ONEWIRE READ PinNbr,0,8,a,b,c,d,e,f,g,h
ONEWIRE RESET PinNbr                        ' reset before command
ONEWIRE WRITE PinNbr, 0, 2, &hcc, &h44      ' start conversion

'read external when b goes high, for parasitic just wait
'IF power = 0 THEN 'parasitic
  'PAUSE 750
'ELSE      ' external power
   't = TIMER
  'DO
    'IF TIMER - t > 1000 THEN
      'Value = 1000
      'EXIT DO
    'ENDIF
    'ONEWIRE READ PinNbr, 6 , 1 , b            ' conversion done?
  'LOOP UNTIL b = 1
'ENDIF
pause (50 << (e+1)/32) ' pause time varies depending on resolution

IF Value = 0 THEN ' we have not timed out yet
  ONEWIRE WRITE PinNbr, 1, 2, &hcc, &hbe      ' command read data
  ONEWIRE READ PinNbr, 2, 2, T1, T2           ' get the data
  ONEWIRE RESET PinNbr
  'print T1,T2, T2 AND &b1000,(T2 AND &b111)
  SELECT CASE fn
    CASE 16 'DS18S20 or DS1820
      ONEWIRE WRITE PinNbr,1,2,&hcc,&hbe
      ONEWIRE READ PinNbr,0,8,a,b,c,d,e,f,g,h
      IF T2 AND &h80 THEN       'if MSB of T2=1 then negative
        'Read 12bit resolution and adjust
        'truncate 0.5deg value (or use integer division \)
        T1 = T1 AND &hFE
        T1=T1 / 2                   'make whole degrees
        'add compensation values read from scratchpad
        T1=T1*16                  'make lsb 1/16 degree
        T1 = T1 -4 +(16 - g)    'add 12 bit value
        'take 2s complement
        T1 = (T1 XOR &hFF) + 1
        Value = -T1/16                'make decimal value in degrees
      ELSE                              'positive temp
        Value = T1 / 2                '9bit value
        'Read 12bit resolution and adjust
        T1 = T1 AND &hFE      'truncate 0.5deg(or use integer division \)
        Value = T1/2- 0.25 + (16 - g) /16   '12 bit value
      ENDIF
    CASE 34, 40 ' DS18S22 or DS18B20
        IF (T2 AND &b1000) THEN       'negative temp
        'make 2s complement (1s complement+1)
        T2 = (T2 XOR &hFF)
        T1 = (T1 XOR &hFF)+1
        IF T1=1 THEN T2=T2+1        'add the carry if required
        Value = -((T2 AND &b111) * 256 + T1) / 16
      ELSE                          'positive temp
        Value = ((T2 AND &b111) * 256 + T1) / 16
      ENDIF
    CASE ELSE
      Value = 1000
  END SELECT
ENDIF
getTemp= Value
END FUNCTION