OPTION EXPLICIT
 COLOUR RGB(WHITE), RGB(BLACK)
 ' reference numbers for the controls are defined as constants
 CONST c_pmp = 2, sw_pmp = 3, tb_flow = 5, tb_fname = 43
 CONST led_run = 6, led_alarm = 7, nbr_hi = 21,  pb_test =23
 ' now draw the "Pump Control" display
 CLS
 GUI INTERRUPT TouchDown, TouchUp
 FONT 3 : GUI CAPTION c_pmp, "Pump", 10, 60, , RGB(BROWN)
 FONT 4 : GUI SWITCH sw_pmp, "ON|OFF", 10, 90, 150, 50, RGB(WHITE),RGB(BROWN)
 CTRLVAL(sw_pmp) = 1
 FONT 3 : GUI DISPLAYBOX tb_flow, 10, 145, 150, 38
 CTRLVAL(tb_flow) = "20.1"
 GUI LED led_run, "Running", 180, 85, 15, RGB(GREEN)
 GUI LED led_alarm, "Alarm", 180, 120, 15, RGB(RED)
 CTRLVAL(led_run) = 1 ' the switch defaults to on so set the LED on
 GUI NUMBERBOX nbr_hi, 10,195,90,40,RGB(YELLOW),RGB(64,64,64)
 GUI TEXTBOX tb_fname, 10, 5, 220, 40, RGB(CYAN), RGB(64,64,64)
 GUI BUTTON pb_test, "TEST", 180, 195, 100, 40,RGB(YELLOW), RGB(RED)
 DO : LOOP
 ' the interrupt routine for touch down
 ' using a select case command it has a different process for each control
SUB TouchDown
 SELECT CASE TOUCH(REF) ' find out the control touched
     
   CASE sw_pmp ' the pump on/off switch
     CTRLVAL(led_run) = CTRLVAL(sw_pmp)
     CTRLVAL(tb_flow) = STR$(CTRLVAL(sw_pmp) * 20.1)
     
 END SELECT
END SUB
 ' interrupt routine when the touch is removed
SUB TouchUp
 SELECT CASE TOUCH(LASTREF) ' use the last reference
   CASE pb_test ' was it the test button
     CTRLVAL(led_alarm) = 1 - CTRLVAL(led_alarm) ' toggle the LED
 END SELECT
END SUB